src/field_manager.f90

説明を見る。

module field_manager

  ! モジュール引用 ; Use statements
  !

  !* gtool **
  !* 

  ! 種類型パラメータ
  ! Kind type parameter 
  !
  use dc_types, only: TOKEN  ! 倍精度実数型. Double precision.

  !* IGMBaseLib **
  !*

  ! 正二十面体格子を管理する管理するクラス
  ! Manager class of icosahedral grid
  !
  use IcGrid2D_FVM_Manager, only: &
    & IcGrid2D_FVM

  ! 正二十面体格子上の物理場データを管理するクラス
  ! Manager class of a physical field data on an icosahedral grid
  !
  use Field_IcGrid2D_Manager, only: &
    & Field_IcGrid2D, &
    & Field_IcGrid2D_Init, paste_field2D_margin
  
  ! 正二十面体格子上の物理場に対して微分演算を提供するクラス
  ! Class providing some differential operators acting on a physcial field on icosahedral grid
  !
  use Derivate_Field_IcGrid2D_Manager, only: &
    & Derivate_Field_IcGrid2D, Derivate_Field_IcGrid2D_Init

  ! 典型的な物理場パターンの生成
  ! Generation of the typical physical fields pattern
  !
  use Field_Pattern_Builder, only: &
    & create_planetaryVorticity_field

  !
  !
  !
  use IcGrid_ncWriter_mod, only: &
    & IcGrid_ncWriter, &
    & IcGrid_ncWriter_Init

  !* IGModel-SW
  !*

  ! シミュレーションパラメータの管理
  ! Manager of simulation parameters
  !
  use param_manager, only: &
    & alpha, Omega

  ! 宣言文 ; Declaration statements
  !
  implicit none
  private
  
  ! 公開変数
  ! Public variables
  !

  ! 各時間レベルを表す配列インデックス管理する変数の宣言.
  ! 時間微分を含む物理場変数は, そうでない変数に対して分別的に時間レベルを管理する.
  !

  integer, public :: TL_Nplus1 = 1
  
  integer, public :: TL_N      = 2

  integer, parameter, public :: TL_NUMS = 2

  integer, public :: TL_DDT_N       = 1
  
  integer, public :: TL_DDT_Nminus1 = 2
  
  integer, public :: TL_DDT_Nminus2 = 3

  integer, parameter, public :: TL_DDT_NUMS = 3

  ! 正二十面格子上の物理場データを管理する構造型 Field_IcGrid2D の変数の宣言.
  !

  type(Field_IcGrid2D), public, save :: xy_Coli
  
  type(Field_IcGrid2D), public, save :: xy_Htopo

  type(Field_IcGrid2D), public, save :: xy_Vel_TL_list(TL_NUMS)
  
  type(Field_IcGrid2D), public, save :: xy_Height_TL_list(TL_NUMS)

  type(Field_IcGrid2D), public, save :: DVelDt_TL_list(TL_DDT_NUMS)
 
  type(Field_IcGrid2D), public, save :: DHeightDt_TL_list(TL_DDT_NUMS)
  
  type(Derivate_Field_IcGrid2D), public :: diff_eval


  ! 公開手続き
  ! Public procedure
  !
  public :: init_field_manager, update_timeLevel

contains

!
subroutine init_field_manager( &
  & icgrid &
  & )

  ! 宣言文 ; Declaration statements
  !
  type(IcGrid2D_FVM), intent(in) :: icgrid
 
  ! 作業変数
  ! Work variables
  !
  integer :: tlID
  
  ! 実行文 ; Executable statements
  !

!  write(*,*) 'init field_manager'

  ! 海底地形の高度場を保持する Field_IcGrid2D クラスのインスタンスの初期化.
  call Field_IcGrid2D_Init(self=xy_Htopo, icgrid=icgrid, name='h_s', rank=1)

  ! 惑星渦度場を保持する Field_IcGrid2D クラスのインスタンスの初期化.
  call Field_IcGrid2D_Init(self=xy_Coli, icgrid=icgrid, name='planetary_vorticity', rank=1)
  call create_planetaryVorticity_field(xy_Coli, Omega, alpha)

  ! タイムレベル n+1,n に対する速度・高度場のデータを保持する Field_IcGrid2D クラスのインスタンスの初期化.
  do tlID=1, TL_NUMS

    call Field_IcGrid2D_Init( &
      & self=xy_Vel_TL_list(tlID), icgrid=icgrid, &
      & name='v', rank=3, long_name='velocity', units='m/s' )

    call Field_IcGrid2D_Init( &
      & self=xy_Height_TL_list(tlID), icgrid=icgrid, &
      & name='h', rank=1, long_name='surface_height', units='m' )

  end do

  ! タイムレベル n, n-1, n-2 の速度・高度場を局所時間微分した場のデータを保持する, 
  ! Field_IcGrid2D クラスのインスタンスの初期化する.
  do tlID=1, TL_DDT_NUMS
    call Field_IcGrid2D_Init( &
      & self=DVelDt_TL_list(tlID), icgrid=icgrid, &
      & name='dvdt', rank=3 )

    call Field_IcGrid2D_Init( &
      & self=DHeightDt_TL_list(tlID), icgrid=icgrid, &
      & name='dhdt', rank=1 )

  end do

  ! 微分演算を提供するクラスのインスタンスを初期化する.
  call Derivate_Field_IcGrid2D_Init(diff_eval, icgrid)

end subroutine init_field_manager

! 
subroutine update_timelevel()

  ! 作業変数 
  ! Work variables
  !
  integer :: tlID

  ! 実行文 ; Executable statement
  !
  
  ! タイムレベル n+ 1 の高度・速度場
  call paste_field2D_margin(xy_Vel_TL_list(TL_Nplus1))
  call paste_field2D_margin(xy_Height_TL_list(TL_Nplus1))

  !
  TL_Nplus1 = get_next_TLid(TL_Nplus1, TL_NUMS)
  TL_N = get_next_TLid(TL_N, TL_NUMS)

  TL_DDT_N = get_next_TLid( TL_DDT_N, TL_DDT_NUMS)
  TL_DDT_Nminus1 = get_next_TLid( TL_DDT_Nminus1, TL_DDT_NUMS)
  TL_DDT_Nminus2 = get_next_TLid( TL_DDT_Nminus2, TL_DDT_NUMS)
  
  !write(*,*) 'dt_n', TL_DDT_N
  !write(*,*) 'dt_n-1', TL_DDT_Nminus1
  !write(*,*) 'dt_n-2', TL_DDT_Nminus2
end subroutine update_timelevel

!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! 
! 非公開手続き
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!
function get_next_TLid( &
  & target_TL, TimeLevelNums  &
  & ) result( NextTLid )
  
  ! 宣言文 ; Declaration statement
  !
  integer, intent(in) :: target_TL
  integer, intent(in) :: TimeLevelNums
  integer nextTLid
  
  ! 実行文 ; Executable statement
  !
  
  nextTLid = target_TL - 1

  if ( nextTLid == 0 ) then
    nextTLid = TimeLevelNums
  end if
end function get_next_TLid

end module field_manager