src/output_field_data.f90

説明を見る。

module output_field_data

  ! モジュール引用 ; Use statements
  !

  ! 種類型パラメータ
  ! Kind type parameter 
  !
  use dc_types, only: DP, &    ! 倍精度実数型. Double precision. 
    &                 TOKEN, &
    &                 STRING !

  ! 座標変換
  ! Coordinate conversion
  !
  use igmcore_coordinate_conversion, only: &
    & orth_to_geo_pos, orth_to_geo_vec

  ! 正二十面体格子の管理
  ! Manager of icosahedral grid
  !
  use IcGrid2D_FVM_Manager, only: &
    & IcGrid2D_FVM, &
    & check_pole, get_EffSize_Min, get_EffSize_Max, &
    & RC_REGIONS_NUM, NOT_POLE_FLAG

  ! 正二十面体格子上の物理場の管理
  ! Manager of the physical field on icosahedral grid
  !
  use Field_IcGrid2D_Manager, only: &
    & Field_IcGrid2D, &
    & get_icgrid, &
    & Field_IcGrid2D_Init
  
  ! 正二十面体格子上の物理場データを NetCDF ファイルに書きだすクラス 
  ! Class to write the data of the physical fields on icosahedral grid into a NetCDF file
  !
  use IcGrid_ncWriter_mod, only: &
    & IcGrid_ncWriter, &
    & IcGrid_ncWriter_Init, open_ncFile, &
    & ncdef_simulation_parameter, ncdef_gridData, ncdef_FieldData, end_ncdef, &
    & write_GridData, write_FieldData, close_ncFile, &
    & increase_recorde_counter

  ! OpenMP
  !
  !
  use omp_lib

  ! 宣言文 ; Declaration statements
  !
  implicit none
  private

  ! 非公開変数
  ! Private variables
  !

  character(Token) :: ncFileName
  
  type(IcGrid_ncWriter), save :: writer

  type(IcGrid_ncWriter), save :: hs_writer

  type(Field_IcGrid2D), save :: UWind
  
  type(Field_IcGrid2D), save :: VWind
  
  type(Field_IcGrid2D), save :: WWind

  type(Field_IcGrid2D), save :: Height

  type(Field_IcGrid2D), save :: HeightS

  integer :: u_ncVarID
  
  integer :: v_ncVarID
  
  integer :: w_ncVarID

  integer :: h_ncVarID

  integer :: hs_ncVarID

  ! 公開関数
  ! Public procedures
  !
  public :: init_output_field_data, output_field, finalize_output_field_data

contains

!
subroutine init_output_field_data( &
  & nc_filename, icgrid,           &            ! (in)
  & integration_time, time_step, output_tick )  ! (in)

  ! モジュール引用 ; Use statements
  !
  use dc_string, only: Replace

  ! 宣言文 ; Declaration statement
  !
  character(*), intent(in) :: nc_filename
  type(IcGrid2D_FVM), intent(in) :: icgrid
  real(DP), intent(in) :: integration_time
  real(DP), intent(in) :: time_step
  real(DP), intent(in) :: output_tick

  ! 作業変数
  ! Work variables
  !
  character(STRING) :: nc_hs_filename 

  ! 実行文 ; Executable statement
  !
  
  ncFileName = nc_filename

  ! IcGrid_ncWriter クラスのインスタンスを初期化. 
  call IcGrid_ncWriter_Init(writer, icgrid)
  call IcGrid_ncWriter_Init(hs_writer, icgrid)

  ! netCDF ファイルを開く. 
  call open_ncFile(writer, nc_filename)
  
  nc_hs_filename = trim(Replace(nc_filename, '.nc', '')) // '_hs.nc' 
  call open_ncFile(hs_writer, nc_hs_filename)

  ! netCDF ファイルへのアウトプットデータの定義
  !

  ! シミュレーションパラメータを NetCDF ファイルに書きだす. 
  call ncdef_Simulation_Parameter(writer, integration_time, time_step, output_tick)
  call ncdef_Simulation_Parameter(hs_writer, integration_time, time_step, output_tick)

  ! 格子点情報を NetCDF ファイルに定義する.  
  call ncdef_GridData(writer)
  call ncdef_GridData(hs_writer)

  ! 速度場と高度場の物理場データ情報を NetCDF ファイルに定義する.  
  call Field_IcGrid2D_Init(UWind, icgrid, 'u', 1, 'zonal_velocity', 'm/s')
  call Field_IcGrid2D_Init(VWind, icgrid, 'v', 1, 'meriodinal_velocity', 'm/s')
  call Field_IcGrid2D_Init(WWind, icgrid, 'w', 1, 'vertical_velocity', 'm/s')
  call Field_IcGrid2D_Init(Height, icgrid, 'h', 1, 'surface_height', 'm')
  call Field_IcGrid2D_Init(HeightS, icgrid, 'hs', 1, 'height_of_underlying_mountain', 'm')

  ! 各 Field_IcGrid2D クラスオブジェクトに対応付けられる NetCDF 内での変数管理 ID を取得する.
  u_ncVarID = ncdef_FieldData(writer, UWind)
  v_ncVarID = ncdef_FieldData(writer, VWind)
  w_ncVarID = ncdef_FieldData(writer, WWind)
  h_ncVarID = ncdef_FieldData(writer, Height)
  hs_ncVarID = ncdef_FieldData(hs_writer, HeightS)

  ! 物理場の定義を終了する. 
  call end_ncdef(writer)
  call end_ncdef(hs_writer)

  ! 格子情報を netCDF に書きこむ. 
  !
  call write_GridData(writer)
  call write_GridData(hs_writer)

end subroutine init_output_field_data

!
subroutine output_field( &
  &  tstep, v_n, h_n, hs     &  ! (in)
  & )

  ! 宣言文 ; Declaration statement
  !
  integer, intent(in) :: tstep
  type(Field_IcGrid2D), intent(in) :: v_n
  type(Field_IcGrid2D), intent(in) :: h_n
  type(Field_IcGrid2D), intent(in), optional :: hs

  ! 作業変数 
  ! Work variables
  !
  type(IcGrid2D_FVM), pointer :: icgrid
  real(DP) :: s_v(3)
  integer :: rcID, i,j
  integer :: EMin, EMax

  ! 実行文 ; Executable statement
  !

  !write(*,*) 'ouput field: tstep=', tstep
  icgrid => get_icgrid(v_n)

  EMin = get_EffSize_Min(icgrid)
  EMax = get_EffSize_Max(icgrid)

  ! デカルト座標系で表されている速度場(ベクトル)データを, 地理座標系で表す. 
  do rcID=1, RC_REGIONS_NUM
    !$omp parallel do private(s_v)
    do j=EMin,EMax
      do i=EMin, EMax
        if ( check_pole(icgrid, rcID,i,j) == NOT_POLE_FLAG ) then
          s_v(:) = orth_to_geo_vec( v_n%val(rcID,i,j,:), orth_to_geo_pos(icgrid%rcs_AGrid(rcID,i,j,:)) )
          
          UWind%val(rcID,i,j,1) = s_v(1)
          VWind%val(rcID,i,j,1) = s_v(2)
          WWind%val(rcID,i,j,1) = s_v(3)
        end if
      end do
    end do
  end do

  Height%val(:,:,:,:) = h_n%val(:,:,:,:)

  ! 時間レベル n の速度場と高度場の情報を netCDF ファイルに書き出す. 
  call write_FieldData(writer, u_ncVarID, UWind)
  call write_FieldData(writer, v_ncVarID, VWind)
  call write_FieldData(writer, w_ncVarID, WWind)
  call write_FieldData(writer, h_ncVarID, Height)

  ! 地形の高度場を NetCDF ファイルに書きだす. 
  ! 地形の高度場については, 初期場に対してのみ書きだす. 
  if( tstep == 0 .and. present(hs) ) then
    HeightS%val(:,:,:,:) = hs%val(:,:,:,:)
    call write_FieldData(hs_writer, hs_ncVarID, HeightS)
    call close_ncFile(hs_writer)
  end if

  ! 時間レベル記録カウンタをインクリメントする. 
  call increase_recorde_counter(writer)

end subroutine output_field

!
subroutine finalize_output_field_data()

  ! 実行文 ; Executable statement
  !
  
  ! NetCDF ファイルの書き出しクラスのオブジェクトを最終化する. 
  call close_ncFile(writer)

end subroutine finalize_output_field_data

end module output_field_data